/* Create hierarchical text file version of SASHELP.CITIDAY */
data _null_;
   file "c:\temp\dinosaur\hier.dat";
   set sashelp.citiday;
   where date between "01oct1988"d and "30apr1989"d;
   by date groupformat;
   format date monyy7.;
   if first.Date then put date year4. +1 date monname. -L ;
   if DCP07 ne . then put @2 date date9. +1 DCP07 8.2;
run;

  /* Create negative values from SASHELP.CITIDAY */
data DowJonesDiff;
  set sashelp.citiday(keep=Date SNYDJCM);
  where SNYDJCM is not missing;
  Difference=snydjcm-lag(snydjcm);
  ActualDifference=Difference;
run;
  /* Create text file with invalid characters from SASHELP.CITIDAY */
data _null_;
   file "c:\temp\dinosaur\emdash.dat";
   set DowJonesDiff(obs=10);
   string=put(Difference,best12.);
   if Difference lt 0 then string=translate(string,"97"x,"-");
   put SNYDJCM string;
run;

  /* Create text file with different date formats from SASHELP.CITIDAY */
data _null_;
   file "c:\temp\dinosaur\datestyles.dat";
   set sashelp.citiday;
   where year(date)=1989 and day(date) in (1,31);
   array formats {3} $ 12 _temporary_ ("yymmdd10.","mmddyy10.","date9.");
   DateString=putn(Date,formats{mod(_n_,3)+1});
   put DateString $10.;
run;